Мозговое умножение

Я только что попытался запустить это в своем (самозапрограммированном) Brainfuck-интерпретаторе и получил 'o', как вы и ожидали. Так что, возможно, у вас проблемы с вашим переводчиком.

Другая возможная (и более вероятная!) причина вашей проблемы заключается в том, что ваши ячейки использовались ранее и все еще имеют значения, не равные нулю. Я предполагаю, что они использовались раньше, потому что вы показываете здесь только небольшую часть своего кода (вы уже напечатали 'hell' (кстати, очень смешно, xD) и пропускаете cell[1]).

Лично я разбил ASCII-таблицу на блоки по 16 символов. Поэтому, если я хочу получить определенный символ, я умножаю 16 на 3 (для цифр), 4 (для прописных букв) или 6 (для строчных букв). Однако для некоторых букв я умножаю 16 на 5 или 7, если это "быстрее" (более короткий код). Например, 'o' я бы получил так:

++++                write 4 in cell(0)
[                   while cell(0) != 0
    >++++           write 4 in cell(1)
    [               while cell(1) != 0
        >+++++++    add 7 to cell(2)
        <-          decrement cell(1)
    ]               go back to 'while cell(1) != 0'
    <-              decrement cell(0)
]                   go back to 'while cell(0) != 0'
>>                  go to cell(2) (has value 4*4*7 = 0x70 or 'p')
-                   decrement cell(2) (it's an 'o' now)
.                   print cell(2)

Я знаю, что Brainf*ck не заботятся об отступах и прочем. Но вы должны подумать о том, чтобы сделать отступ в коде, потому что это облегчает чтение.

Давайте посмотрим на ваш код:

+++++                  intialize counter (cell #0) to 5
[                      use loop to set cell #2 to 10
    >>++                   add 2 to cell #2
    <<-                
]
[-]                    does actually nothing
>>+                    add 1 to cell #2
[                      use outside with cell #2 as counter
    <<+++++            sets cell #0 to 5
    [                  use inner loop to add 10 to cell #3
        >>>++
        <<<-
    ]
    >>-
]
>+.                    add 1 to cell #3 and print result

Ваш код на самом деле работает так, как ожидалось, причина того, что он не работает, может заключаться в том, что код, который выполняется перед этой частью, устанавливает для ячеек другие начальные значения.

Это много кода, чтобы просто напечатать «о», вы могли бы напечатать его после первого цикла из ячейки № 2, второй цикл не нужен. Вот пример печати «Hello World» с помощью Brainf*ck:

+++++ +++++             initialize counter (cell #0) to 10
[                       use loop to set 70/100/30/10
    > +++++ ++              add  7 to cell #1
    > +++++ +++++           add 10 to cell #2
    > +++                   add  3 to cell #3
    > +                     add  1 to cell #4
<<<< -                  decrement counter (cell #0)
]
> ++ .                  print 'H'
> + .                   print 'e'
+++++ ++ .              print 'l'
.                       print 'l'
+++ .                   print 'o'
> ++ .                  print ' '
<< +++++ +++++ +++++ .  print 'W'
> .                     print 'o'
+++ .                   print 'r'
----- - .               print 'l'
----- --- .             print 'd'
> + .                   print '!'
> .                     print '\n'

Следующий веб-сайт может помочь вам протестировать код Brainf*ck: Brainfck Visualizer.