D: Наследование статических переменных, дифференциация по классам?

Статическая переменная в классе является частью этого класса и только частью этого класса. Во всей программе существует один его экземпляр, независимо от того, сколько экземпляров этого класса было создано или сколько классов было получено из него. Статические переменные-члены не наследуются больше, чем обычные переменные-члены. Производные классы имеют доступ к базовой переменной, если она общедоступна или защищена, но они не получают свою собственную копию. Ничего не копируется в цепочке производных классов. Переменные-члены существуют в классе, в котором они объявлены, а производные классы потенциально имеют к ним доступ, но производные классы не получают свою собственную копию.

Таким образом, помещая dict в MyBase, вы создаете один из них для всей своей программы, независимо от того, что делают его производные классы. Если вы хотите, чтобы каждый из ваших производных классов имел свою собственную копию, тогда каждый из них должен будет объявить свою собственную копию.

Теперь вы можете свести к минимуму дублирование кода с помощью миксина шаблона или миксина строки, но вам все равно придется смешивать его с каждым производным классом. Например, вы можете сделать это

import std.stdio;

mixin template Dict()
{
    static string[string] dict;
    static void attach(string key, string val)
    {
        dict[key] = val;
    }
}

class MyBase
{
    mixin Dict;
}

class MySubA : MyBase
{
    mixin Dict;
    // various unique member variables
}

class MySubB : MyBase
{
    mixin Dict;
    // ...
}

void main()
{
    MySubA.attach("a", "a1");
    MySubB.attach("b", "b1");
    writefln("-:%s", MyBase.dict);
    writefln("A:%s", MySubA.dict);
    writefln("B:%s", MySubB.dict);
}

Ах, похоже, я только что наткнулся на решение.

class MyBase(T) {
    static string[string] dict;
    static void append(string key, string val) {
        dict[key] = val;
    }
}
class MySubA : MyBase!MySubA {
    // various unique member variables
}
class MySubB : MyBase!MySubB {
    // ...
}

делает именно то, что я хотел. Размещение собственного ответа в соответствии с быстрым поиском этикета.

Если вам не нужна иерархия:

import std.stdio;

mixin template Dict()
{
    static string[string] dict;
    static void attach(string key, string val)
    {
        dict[key] = val;
    }
}

class MySubA
{
    mixin Dict;
}

class MySubB
{
    mixin Dict;
}

void main()
{
    MySubA.attach("a", "a1");
    MySubB.attach("b", "b1");
    writefln("A:%s", MySubA.dict);
    writefln("B:%s", MySubB.dict);
}

Я думаю, что это лучшее решение, чем это наследование шаблонов.